Ray Bundles Near a Spinning Black Hole - Derivation of Equations
Document number kip.spin.3nb.derive

Kip, Rutherford, 12 August 2013; Revised 12 September 2013 for change in definition of ℓ; Cleaned up 14 September 2013; Annotated for others ease of reading  18 September 2014

Based on the analysis of Serge Pineault and Robert Roeder [P&R]:

"Applications of geometrical optics to the Kerr metric.  I. Analytical Results," Astrophysical Journal, 212, 541 - 549 (1977)

"Applications of geometrical optics to the Kerr metric.  II. Numerical results,” Astrophysical Journal, 213, 548 - 557 (1977)

I. Covariant LNRF Components of Riemann Tensor in Kerr Spacetime

A.  Components from Bardeen, Press and Teukolsky [BPT] Eq. (3.7), using MTW conventions, but using w for what BPT call z (to agree with Pineault and Roeder)

References :

BPT: James M. Bardeen, William H. Press and Saul A. Teukolsky, "Rotating black holes: Locally nonrotating frames, energy extraction, and scalar synchrotron radiation," Astrophysical Journal, 178, 347 - 369 (1972).

MTW : Charles W. Misner, Kip S. Thorne, and John A. Wheeler, Gravitation (WH Freeman, 1973)

Rtϕtϕ=Q1;

Rrθrθ=-Rtϕtϕ;

Rtϕrθ=-Q2;

Rtrtr=-Q1(2+w)/(1-w);

Rϕθϕθ=-Rtrtr;

Rtrtθ=S Q2;

Rϕrϕθ=Rtrtθ;

Rtrϕr=S Q1;

Rtθϕθ=-Rtrϕr;

Rtrϕθ=-Q2(2+w)/(1-w);

Rtθtθ=Q1(1+2w)/(1-w);

Rϕrϕr=-Rtθtθ;

Rtθϕr=-Q2(1+2w)/(1-w);

I have checked these against Eqs. (I, A4) of P&R, who took them from BPT and use opposite sign.

B. All Components of Riemann

R=Table[0,{i,1,4},{j,1,4},{k,1,4},{l,1,4}];

R[[4,2,3,1]]

set 1 = r, 2 = θ, 3 = ϕ, 4 = t

R[[4,3,4,3]]=Rtϕtϕ;R[[3,4,3,4]]=Rtϕtϕ;R[[3,4,4,3]]=-Rtϕtϕ;R[[4,3,3,4]]=-Rtϕtϕ;

R[[1,2,1,2]]=Rrθrθ; R[[2,1,2,1]]=Rrθrθ; R[[2,1,1,2]]=-Rrθrθ; R[[1,2,2,1]]=-Rrθrθ;

R[[4,3,1,2]]=Rtϕrθ; R[[3,4,1,2]]=-Rtϕrθ; R[[4,3,2,1]]=-Rtϕrθ;R[[3,4,2,1]]=Rtϕrθ; R[[1,2,4,3]]=Rtϕrθ; R[[2,1,4,3]]=-Rtϕrθ; R[[1,2,3,4]]=-Rtϕrθ; R[[2,1,3,4]]=Rtϕrθ;

R[[4,1,4,1]]=Rtrtr;R[[1,4,4,1]]=-Rtrtr;R[[4,1,1,4]]=-Rtrtr;R[[1,4,1,4]]=Rtrtr;

R[[3,2,3,2]]=Rϕθϕθ;R[[2,3,3,2]]=-Rϕθϕθ;R[[3,2,2,3]]=-Rϕθϕθ;R[[2,3,2,3]]=Rϕθϕθ;

R[[4,1,4,2]]=Rtrtθ;R[[1,4,4,2]]=-Rtrtθ;R[[4,1,2,4]]=-Rtrtθ;R[[1,4,2,4]]=Rtrtθ;R[[4,2,4,1]]=Rtrtθ;R[[2,4,4,1]]=-Rtrtθ;R[[4,2,1,4]]=-Rtrtθ;R[[2,4,1,4]]=Rtrtθ;

R[[3,1,3,2]]=Rϕrϕθ;R[[1,3,3,2]]=-Rϕrϕθ;R[[3,1,2,3]]=-Rϕrϕθ;R[[1,3,2,3]]=Rϕrϕθ;R[[3,2,3,1]]=Rϕrϕθ;R[[2,3,3,1]]=-Rϕrϕθ;R[[3,2,1,3]]=-Rϕrϕθ;R[[2,3,1,3]]=Rϕrϕθ;

R[[4,1,3,1]]=Rtrϕr;R[[1,4,3,1]]=-Rtrϕr;R[[4,1,1,3]]=-Rtrϕr;R[[1,4,1,3]]=Rtrϕr;R[[3,1,4,1]]=Rtrϕr;R[[1,3,4,1]]=-Rtrϕr;R[[3,1,1,4]]=-Rtrϕr;R[[1,3,1,4]]=Rtrϕr;

R[[4,2,3,2]]=Rtθϕθ;R[[2,4,3,2]]=-Rtθϕθ;R[[4,2,2,3]]=-Rtθϕθ;R[[2,4,2,3]]=Rtθϕθ;R[[3,2,4,2]]=Rtθϕθ;R[[2,3,4,2]]=-Rtθϕθ;R[[3,2,2,4]]=-Rtθϕθ;R[[2,3,2,4]]=Rtθϕθ;

R[[4,1,3,2]]=Rtrϕθ;R[[1,4,3,2]]=-Rtrϕθ;R[[4,1,2,3]]=-Rtrϕθ;R[[1,4,2,3]]=Rtrϕθ;R[[3,2,4,1]]=Rtrϕθ;R[[2,3,4,1]]=-Rtrϕθ;R[[3,2,1,4]]=-Rtrϕθ;R[[2,3,1,4]]=Rtrϕθ;

R[[4,2,4,2]]=Rtθtθ;R[[2,4,4,2]]=-Rtθtθ;R[[4,2,2,4]]=-Rtθtθ;R[[2,4,2,4]]=Rtθtθ;

R[[3,1,3,1]]=Rϕrϕr;R[[1,3,3,1]]=-Rϕrϕr;R[[3,1,1,3]]=-Rϕrϕr;R[[1,3,1,3]]=Rϕrϕr;

R[[4,2,3,1]]=Rtθϕr;R[[2,4,3,1]]=-Rtθϕr;R[[4,2,1,3]]=-Rtθϕr;R[[2,4,1,3]]=Rtθϕr;R[[3,1,4,2]]=Rtθϕr;R[[1,3,4,2]]=-Rtθϕr;R[[3,1,2,4]]=-Rtθϕr;R[[1,3,2,4]]=Rtθϕr;

TensorSymmetry[R]

R[[1,4,1,4]]/.w->0

R[[3,4,3,4]]

R[[1,3,1,3]]/.w->0

II. Ψos = Driving Term for Geodesic Deviation

Work out the driving term for evolution of the displacement vectors ξ and η of Pineault and Roeder [P&R]

A. Various vectors and scalars for use in the analysis [from Pineault and Roeder]

From P&R Eqs. (6), The transverse vector m = (eθ + ieϕ)/Sqrt[2] has contravariant components

mu=Table[0,{4}];mu[[2]]=1/Sqrt[2];mu[[3]]=I/Sqrt[2];

mu

Note that I put the time index last (the fourth index), whereas PP&R put it first

Also from P&R, Eqs. (6), changing the longitudinal vector to ℓ = (et + er)/Sqrt[2] to make the ray bundle equations robust for my case, bundles that come inward from the celestial sphere; the P&R choice ℓ = (et - er)/Sqrt[2] makes the equations robust for bundles that travel outward to the celestial sphere but asymptotically unstable for my case

ℓu=Table[0,{4}];ℓu[[1]]=+1/Sqrt[2];ℓu[[4]]=1/Sqrt[2];

ℓu

The propagation vector k (denoted p in my paper with the Dneg team for Classical and Quantum Gravity) has contravariant components in the Boyer-Lindquist orthonormal basis associated with the proper reference frame of a Locally Nonrotating Observer (language of BPT), i.e. the frame of a FIDO (my usual language) -- an observer whose world line is orthogonal to the time slices of the Boyer-Lindquist coordinate system:

ku={kr,kθ,kϕ,kt}

and covariant components

kd={kr,kθ,kϕ,-kt}

and note that its null nature means that the time component has a value

ktv = Sqrt[kr^2+kθ^2+kϕ^2]

The scalar Γ then has the value

Γv=FullSimplify[kd.mu/kd.ℓu]

The vector t*, which I shall denote ts, then has contravariant components [P&R Eq. (9)]

tsu=mu-Γ ℓu

which agrees with P&R Eq. (7)

The P&R vectors a and b are

au=Simplify[Re[Expand[Sqrt[2] (tsu-tsu[[4]]/ku[[4]] ku)/.Γ->Γv]],{kt,kr,kθ,kϕ,1,1/(kr-kt),1/kt}∈Reals]

bu=Simplify[Im[Expand[Sqrt[2] (tsu-tsu[[4]]/ku[[4]] ku)/.Γ->Γv]],{kt,kr,kθ,kϕ,1,1/(kr-kt),1/kt}∈Reals]

Check orthonormality

Simplify[{au.au,au.bu,bu.bu,ku.au,ku.bu}/.kt->Sqrt[kr^2+kθ^2+kϕ^2]]

B. The Weyl Scalar Ψos that Drives Geodesic Deviation

In MTW conventions Ψos = +R (k, ts, k, ts) whereas in P&R conventions Ψos = -R (k, ts, k, ts).  Since we differ in sign of Riemann, this should give the same Ψos in both conventions.  See page 14 of my 5 August hand calculations.

Ψos=FullSimplify[ku.(tsu.(ku.(tsu.R)))/.Γ->Γv]

E. Real and Imaginary Parts of my Ψos

1. Real Part in form for use in computer programs

ReΨos=Simplify[Re[Expand[Numerator[Ψos]]],{w,kr,kθ,kϕ,kt,Q1,Q2,S}∈Reals]/Denominator[Ψos]

ReΨosInputForm=InputForm[ReΨos]

2. Real Part in form for use in kip.spin.3 pdf file

ReΨos=Simplify[Re[Expand[Numerator[Ψos]]],{w,kr,kθ,kϕ,kt,Q1,Q2,S}∈Reals]/Denominator[Ψos]

ReΨosN1=Simplify[Coefficient[Numerator[ReΨos],Q1]]Q1

ReΨosN2=Simplify[Coefficient[Numerator[ReΨos],Q2]Q2]

ReΨosD=Denominator[ReΨos]

Simplify[(ReΨosN1+ReΨosN2)/ReΨosD-ReΨos]

TeXForm[ReΨosN1]

TeXForm[ReΨosN2]

TeXForm[ReΨosD]

2. Imaginary Part in Form for use in computer programs

ImΨos=Simplify[Im[Expand[Numerator[Ψos]]],{w,kr,kθ,kϕ,kt,Q1,Q2,S}∈Reals]/Denominator[Ψos]

ImΨosInputForm=InputForm[ImΨos]

Verify

Simplify[ReΨos+I ImΨos - Ψos]

4. Imaginary Part in form for use in kip.spin.3 pdf file

ImΨosN1=Simplify[Coefficient[Numerator[ImΨos],Q1]]Q1

ImΨosN2=Simplify[Coefficient[Numerator[ImΨos],Q2]Q2]

ImΨosD=Denominator[ImΨos]

Simplify[(ImΨosN1+ImΨosN2)/ImΨosD-ImΨos]

TeXForm[ImΨosN1]

TeXForm[ImΨosN2]

TeXForm[ImΨosD]

III. ℳ=dχ/dζ : Angle for Parallel Transport

A. Connection Coefficients  in locally nonrotating reference frame (FIDO frame)

1. Metric Functions for use in Computing Connection Coefficients

Clear[αv,a]

ρ2v=r^2+a^2 Cos[θ]^2;

ρv=Sqrt[ρ2v];

Δv=r^2-2r+a^2;

Σ2v=(r^2+a^2)^2-a^2Δv Sin[θ]^2;

Σv=Sqrt[Σ2v];

ωv=2 a r/Σ2v;

ϖv=Σv Sin[θ]/ρv;

αv=ρv Sqrt[Δv]/Σv;

νv=Log[αv];

μ1v=Log[ρv/Sqrt[Δv]];

μ2v=Log[ρv];

ψv=Log[ϖv];

2. Connection Coefficients Computed using BPT Formulae

These are the covariant (all indices down) connection coefficients

Γtrt=FullSimplify[-D[νv,r]Exp[-μ1v]]

Γrtt=-Γtrt;

Γtrϕ=FullSimplify[-1/2  D[ωv,r]Exp[ψv-νv-μ1v]]

Γrtϕ=-Γtrϕ;

Γtθt=FullSimplify[-D[νv,θ]Exp[-μ2v]]

Γθtt=-Γtθt;

Γtθϕ=FullSimplify[-1/2  D[ωv,θ] Exp[ψv-νv-μ2v]]

Γθtϕ=-Γtθϕ;

Γtϕr=FullSimplify[-1/2 D[ωv,r]Exp[ψv-νv-μ1v]]

Γϕtr=-Γtϕr;

Γtϕθ=FullSimplify[-1/2 D[ωv,θ]Exp[ψv-νv-μ2v]]

Γϕtθ=-Γtϕθ;

Γrθr=FullSimplify[D[μ1v,θ]Exp[-μ2v]]

Γθrr=-Γrθr;

Γrθθ=FullSimplify[-D[μ2v,r]Exp[-μ1v]]

Γθrθ=-Γrθθ;

Γrϕϕ=FullSimplify[-D[ψv,r]Exp[-μ1v]]

Γϕrϕ=-Γrϕϕ;

Γrϕt=FullSimplify[1/2 D[ωv,r]Exp[ψv-νv-μ1v]]

Γϕrt=-Γrϕt;

Γθϕϕ=FullSimplify[-D[ψv,θ]Exp[-μ2v]]

Γϕθϕ=-Γθϕϕ;

Γθϕt=FullSimplify[1/2 D[ωv,θ]Exp[ψv-νv-μ2v]]

Γϕθt=-Γθϕt;

B. Expression for ℳ= dχ/dζ

1. Initial Expression

This is P & R Eq. (14) changed for my change of definition of ℓ - and with connection coefficient indices all down and wave vector indices all up:

dχdζ=FullSimplify[Γθϕt kt + Γθϕϕ kϕ + 1/(kt-kr)(kϕ(-Γtθt kt -Γtθϕ kϕ -Γrθr kr - Γrθθ kθ) -kθ(-Γtϕr kr - Γtϕθ kθ -Γrϕt kt -Γrϕϕ kϕ))]

For a nonrotating black hole:

dχdζ/.a->0

2. Rearrange Terms

Den=Denominator[dχdζ]

Denk=4(kr-kt)ρ^3Σ^2

FullSimplify[Den-Denk/.{ρ->ρv,Σ->Σv}]

Num=Numerator[dχdζ]

Numk=Simplify[(Num/.Sqrt[a^2+(-2+r)r]->Sqrt[Δ])/.(a^2+(-2+r)r)->Δ]

FullSimplify[(Numk/Denk - dχdζ)/.{Δ->Δv,ρ->ρv,Σ->Σv}]

NumNoK=Simplify[Coefficient[Num,(kr-kt)]](kr-kt)

NumWithK=Simplify[Num-NumNoK]

NumWithKWithkθ2mkϕ2=Coefficient[NumWithK,(kθ^2-kϕ^2)](kθ^2-kϕ^2)

NumWithKNokθ2mkϕ2=FullSimplify[NumWithK-NumWithKWithkθ2mkϕ2]

NumWithKNokθ2mkϕ2Withkϕ=FullSimplify[Coefficient[NumWithKNokθ2mkϕ2,kϕ]kϕ]

NumWithKNokθ2mkϕ2Nokϕ=FullSimplify[NumWithKNokθ2mkϕ2-NumWithKNokθ2mkϕ2Withkϕ]

NumNoK1=FullSimplify[(NumNoK+NumWithKNokθ2mkϕ2Nokϕ)/.Sqrt[a^2+(-2+r)r]->Sqrt[Δ]]

3. Final Answer

ℳ=((1/Denk)(NumNoK1+ NumWithKWithkθ2mkϕ2+NumWithKNokθ2mkϕ2Withkϕ)/.Sqrt[a^2+(-2+r)r]->Sqrt[Δ])/.(a^2+(-2+r)r)->Δ

Check :

FullSimplify[(ℳ-dχdζ)/.{Δ->Δv,Σ->Σv,ρ->ρv}]

ℳInputForm=InputForm[ℳ]

TeXForm[ℳ]

IV. Final Answers for ℳ and Ψos - in forms for use in computer programs

ℳ

ℳInputForm

ReΨos

ReΨosInputForm

ImΨos

ImΨosInputForm