* EE114b Fianl Project test bench, Winter 2002-2003
* 1.75GHz transimpedance pre-amplifier
*
*
**********************************************************


*To include the model file
.INCLUDE model25.txt


*To include the project subckt file (i.e. design file)
.INCLUDE "project1.hsp"


*Necessary options for your simulations
.option post accurate


*Subcircuit definition in test-bench for "single-ended input"
xpreamp1 nin noutp noutn nVdd nGnd	preamp


*Subcircuit definition in test-bench for "differential input"
*xpreamp1 ninp ninn noutp noutn nVdd nGnd	preamp


*Voltage source and ground definition  
Vdd	nVdd	0	2.5
Vgnd	nGnd	0	0


*Input current source and capacitance definition for "single-ended input"
Iin	nin	0	DC	0	AC	1	sin(0  5m  100meg)
CD	nin	0	500f

*For slew-rate simulation in single-balanced input
*Iin	nin	0	pwl	1p 0   1n 0   1.001n 1   10n 1



*Input current source and capacitance definition for "differential input"
*Iin	ninp	ninn	DC	0	AC	1	sin(0  5m  100meg)
*CD	ninp	ninn	500f

*For slew-rate simulation in differential input
*Iin	ninp	ninn	pwl	1p 0   1n 0   1.001n 1   10n 1



*Output coupling capacitors and 50ohm loads
Coutp	noutp	nop	1u
Coutn	noutn	non	1u
Routp	nop	0	50
Routn	non	0	50



*To see operating points, and current consumption in output file
.OP


*To simulate gain, bandwidth
.AC	DEC	100	5k	5g


*To simulate maximum swing
.TRAN	1n	50n


*To simulate slew-rate
*.TRAN	1p	10n


*To see differential output in mwaves
.PLOT AC V(noutp,noutn)	
.PLOT TRAN V(noutp,noutn)

.END